POI importálás

A POI-kat az Openstreetmap előzetesen szűrt adataiból válogatjuk. A lekérdezéshez az Overpass Turbo eszközt használjuk. A folyamat a következő:

Előzetes szűrés az OSM adatai közt

Az Overpass Turboban lefuttatjuk a lekérdezést, majd az eredményt geojson formában exportáljuk

Importálás a heyjoe.hu adatbázisába

az OSM-ből kinyert geojsont elmentjük a heyjoe.hu adatbázisába

Manuális válogatás

a szerkesztők a heyjoe.hu adminisztrációs felületén egyesével végignézik az előzetesen már megszűrt pontokat, és az ajánlásra érdemeseket rögzítik a poi táblába, illetve törlik a nem megfelőket onnan.

A szerkesztőknek alapvetően csak a harmadik pont, a manuális válogatás lesz a feladatuk.

Kategóriák

Az alábbi kategóriába soroljuk a látnivalókat. Egy-egy pont több kategóriában is önállóan szerepelhet. A példákban túramozgalomra, általában az okt-re vonatkozóan szerepel az azonosító.

A lekérdezés a következő fő részekből áll:

Fejléc

 [out:json][timeout:1625];

meghatározza az adatok formátumát, és a lekérdezés futásidejét.

Szűrés helyszín szerint

 {{geocodeArea:Hungary}}->.searchArea;(rel(3020505);(._;>;);)->.okt;

az adatok helyszínét Magyarországra korlátozza, illetve beállítja a mozgalom útvonalát

szűrés címkék szerint

node["historic"="manor"][name](around.okt:1500)(area.searchArea);

A node, way, relation az adat tipusára utal (pont, vonal, kapcsolat). A ["historic"="manor"] megadott tulajdonságok alapján szűr. A [name] csak azokat a pontokat gyűjti ki, ahol a név meg van adva. A Az (around.okt:1500)(area.searchArea) pedig az országon belül, a megadott mozgalom útvonalától maximum 1500 méterre lévő objektumokra szűkíti a keresést.

Kimenet

out center;

Az eredményeket csak egy pontként kapjuk meg, akkor is, ha vonalak, vagy felületek.

Várak, kastélyok, kúriák

1500 méternél nem messzebb fekvő pontok kerülnek a lekérdezésbe: kúriák, várak, romok, amiknek a nevében szerepel a kastély, vagy a vár szó, és a definiáltan várromok.

 [out:json][timeout:1625];
 {{geocodeArea:Hungary}}->.searchArea;
 (rel(3020505);
 (._;>;);
 )->.okt;

 (
    node["historic"="manor"][name](around.okt:1500)(area.searchArea);
    way["historic"="manor"][name](around.okt:1500)(area.searchArea);
    relation["historic"="manor"][name](around.okt:1500)(area.searchArea);
    node["historic"="castle"][name](around.okt:1500)(area.searchArea);
    way["historic"="castle"][name](around.okt:1500)(area.searchArea);
    relation["historic"="castle"][name](around.okt:1500)(area.searchArea);
    node["historic"="ruins"]["name"~"kastély|vár"](around.okt:1500)(area.searchArea);
    way["historic"="ruins"]["name"~"kastély|vár"](around.okt:1500)(area.searchArea);
    relation["historic"="ruins"]["name"~"kastély|vár"](around.okt:1500)(area.searchArea);
    node["ruins"="castle"][name](around.okt:1500)(area.searchArea);
    way["ruins"="castle"][name](around.okt:1500)(area.searchArea);
    relation["ruins"="castle"][name](around.okt:1500)(area.searchArea);
 );

 out center;

Futtatható lekérdezés: https://overpass-turbo.eu/s/1ct4 Figyelem, hosszú, több perces lekérdezési idő!